1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
|
#define BA_UART_MODEM 0xFFFF5800
#
.macro senduart, rd, rx
strb \rd, [\rx, #0]
.endm
.macro busyuart, rd, rx
1001:
@busy waiting until THR is empty
ldrb \rd, [\rx, #5] @ read LSR register
mov \rd, \rd, lsr #6
tst \rd, #1
beq 1001b
.endm
.macro loadsp, rd
ldr \rd, =BA_UART_MODEM
.endm
.EQU ARM_MODE_FIQ, 0x11
.EQU ARM_MODE_IRQ, 0x12
.EQU ARM_MODE_SVC, 0x13
.EQU I_BIT, 0x80
.EQU F_BIT, 0x40
#define TOP_OF_RAM 0x083fff0
#define FIQ_STACK_SIZE 1024
#define IRQ_STACK_SIZE 1024
.section .text._start
.globl _start
_start:
@ clear bss section
.global __bss_start
.global __bss_end
mov r0, #0
ldr r1, =__bss_start
ldr r2, =__bss_end
2: cmp r1, r2
strlo r0, [r1], #4
blo 2b
ldr r0, =TOP_OF_RAM
/* initialize FIQ stack */
msr CPSR_c, #ARM_MODE_FIQ | I_BIT | F_BIT
mov r13, r0
sub r0, r0, #FIQ_STACK_SIZE
/* initialize IRQ stack */
msr CPSR_c, #ARM_MODE_IRQ | I_BIT | F_BIT
mov r13, r0
sub r0, r0, #IRQ_STACK_SIZE
/* initialize supervisor stack */
msr CPSR_c, #ARM_MODE_SVC | I_BIT | F_BIT
mov r13, r0
@ set backlight to moderate level
bl pwl_init
mov r0, #50
bl pwl_set_level
@ldr r0, =string
@bl puts_asm
@ some memory dumps
@ldr r0, =0xfffef000
@bl memdump
@ldr r0, =0xfffffe00
@bl memdump
ldr pc, _jump_main
@ endless loop at end of program
_end: b _end
b _start
_jump_main: .word main
string: .word 0x6c6c6548
.word 0x6f57206f
.word 0x00646c72
foo: .word 0xee4c9f63
bar: .word 0x639f4cee
.align 2
.type phexbuf, #object
phexbuf: .space 12
.size phexubf, . - phexbuf
.globl phex
phex: adr r3, phexbuf
mov r2, #0
strb r2, [r3, r1]
1: subs r1, r1, #1
movmi r0, r3
bmi puts_asm
and r2, r0, #15
mov r0, r0, lsr #4
cmp r2, #10
addge r2, r2, #7
add r2, r2, #'0'
strb r2, [r3, r1]
b 1b
puts_asm: loadsp r3
1: ldrb r2, [r0], #1
teq r2, #0
moveq pc, lr
2: senduart r2, r3
busyuart r1, r3
teq r2, #'\n'
moveq r2, #'\r'
beq 2b
teq r0, #0
bne 1b
mov pc, lr
.globl putchar_asm
putchar_asm:
mov r2, r0
mov r0, #0
loadsp r3
b 2b
memdump: mov r12, r0
mov r10, lr
mov r11, #0
2: mov r0, r11, lsl #2
add r0, r0, r12
mov r1, #8
bl phex
mov r0, #':'
bl putchar_asm
1: mov r0, #' '
bl putchar_asm
ldr r0, [r12, r11, lsl #2]
mov r1, #8
bl phex
and r0, r11, #7
teq r0, #3
moveq r0, #' '
bleq putchar_asm
and r0, r11, #7
add r11, r11, #1
teq r0, #7
bne 1b
mov r0, #'\n'
bl putchar_asm
cmp r11, #64
blt 2b
mov pc, r10
#define ASIC_CONF_REG 0xfffef008
#define BA_PWL 0xfffe8000
pwl_init: ldr r1, =ASIC_CONF_REG
ldr r2, [r1]
orr r2, r2, #0x10 @ set light output to PWL
str r2, [r1]
ldr r1, =BA_PWL
mov r0, #1
strb r0, [r1, #1] @ enable clock of PWL unut
mov pc, lr
pwl_set_level: ldr r1, =BA_PWL
strb r0, [r1]
mov pc, lr
handle_abort:
@ print the PC we would jump back to...
sub lr, lr, #4 @ we assume to be ARM32
mov r0, lr
mov r1, #8
bl phex
@ print abort message
mov r0, #'A'
bl putchar_asm
mov r0, #'B'
bl putchar_asm
mov r0, #'O'
bl putchar_asm
mov r0, #'R'
bl putchar_asm
mov r0, #'T'
bl putchar_asm
0: @ dead
b 0b
irq_entry:
/* Adjust and save LR_irq in IRQ stack */
sub lr, lr, #4
stmfd sp!, {lr}
/* Save SPSR for nested interrupt */
mrs r14, SPSR
stmfd sp!, {r14}
/* Call the interrupt handler C function */
stmfd sp!, {r0-r4, r12}
bl irq
ldmfd sp!, {r0-r4, r12}
/* Restore SPSR_irq from IRQ stack */
ldmia sp!, {r14}
msr SPSR_cxsf, r14
/* Restore adjusted LR_irq from IRQ stack directly in the PC */
ldmia sp!, {pc}^
fiq_entry:
/* Adjust and save LR_irq in IRQ stack */
sub lr, lr, #4
stmfd sp!, {lr}
/* Save SPSR for nested interrupt */
mrs r14, SPSR
stmfd sp!, {r14}
/* Call the interrupt handler C function */
stmfd sp!, {r0-r4, r12}
bl fiq
ldmfd sp!, {r0-r4, r12}
/* Restore SPSR_irq from IRQ stack */
ldmia sp!, {r14}
msr SPSR_cxsf, r14
/* Restore adjusted LR_irq from IRQ stack directly in the PC */
ldmia sp!, {pc}^
/* Exception Vectors like they are needed for the exception vector
indirection of the internal boot ROM. The following section must be liked
to appear at 0x80'001c */
.section .text.exceptions
_undef_instr:
b handle_abort
_sw_interr:
b _sw_interr
_prefetch_abort:
b handle_abort
_data_abort:
b handle_abort
_reserved:
b _reserved
_irq:
b irq_entry
_fiq:
b fiq_entry
|