9 files changed, 278 insertions, 172 deletions
diff --git a/Makefile.am b/Makefile.am
index be4ec0436c..57af9bf0b9 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -24,7 +24,7 @@ include ./Makefile.am.inc
 AM_DISTCHECK_CONFIGURE_FLAGS=@GUI_CONFIGURE_FLAGS@
 # Make sure to keep ACLOCAL_AMFLAGS in Makefile.am and AC_CONFIG_MACRO_DIRS
 # in configure.ac in sync, otherwise there will be an error running autogen.sh.
-ACLOCAL_AMFLAGS = `./aclocal-flags`
+ACLOCAL_AMFLAGS = -I ./aclocal-fallback
 
 # Common headers
 COMMONCPPFLAGS =
@@ -709,7 +709,7 @@ EXTRA_DIST = \
 	aclocal-fallback/ax_prog_cc_for_build.m4	\
 	aclocal-fallback/libsmi.m4			\
 	aclocal-fallback/libgcrypt.m4			\
-	aclocal-flags		\
+	aclocal-fallback/pkg.m4				\
 	autogen.sh		\
 	capinfos.c		\
 	captype.c		\
diff --git a/aclocal-fallback/pkg.m4 b/aclocal-fallback/pkg.m4
new file mode 100644
index 0000000000..fb6f48c47e
--- /dev/null
+++ b/aclocal-fallback/pkg.m4
@@ -0,0 +1,275 @@
+dnl pkg.m4 - Macros to locate and utilise pkg-config.   -*- Autoconf -*-
+dnl serial 11 (pkg-config-0.29.1)
+dnl
+dnl Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
+dnl Copyright © 2012-2015 Dan Nicholson <dbn.lists@gmail.com>
+dnl
+dnl This program is free software; you can redistribute it and/or modify
+dnl it under the terms of the GNU General Public License as published by
+dnl the Free Software Foundation; either version 2 of the License, or
+dnl (at your option) any later version.
+dnl
+dnl This program is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+dnl General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU General Public License
+dnl along with this program; if not, write to the Free Software
+dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
+dnl 02111-1307, USA.
+dnl
+dnl As a special exception to the GNU General Public License, if you
+dnl distribute this file as part of a program that contains a
+dnl configuration script generated by Autoconf, you may include it under
+dnl the same distribution terms that you use for the rest of that
+dnl program.
+
+dnl PKG_PREREQ(MIN-VERSION)
+dnl -----------------------
+dnl Since: 0.29
+dnl
+dnl Verify that the version of the pkg-config macros are at least
+dnl MIN-VERSION. Unlike PKG_PROG_PKG_CONFIG, which checks the user's
+dnl installed version of pkg-config, this checks the developer's version
+dnl of pkg.m4 when generating configure.
+dnl
+dnl To ensure that this macro is defined, also add:
+dnl m4_ifndef([PKG_PREREQ],
+dnl     [m4_fatal([must install pkg-config 0.29 or later before running autoconf/autogen])])
+dnl
+dnl See the "Since" comment for each macro you use to see what version
+dnl of the macros you require.
+m4_defun([PKG_PREREQ],
+[m4_define([PKG_MACROS_VERSION], [0.29.1])
+m4_if(m4_version_compare(PKG_MACROS_VERSION, [$1]), -1,
+    [m4_fatal([pkg.m4 version $1 or higher is required but ]PKG_MACROS_VERSION[ found])])
+])dnl PKG_PREREQ
+
+dnl PKG_PROG_PKG_CONFIG([MIN-VERSION])
+dnl ----------------------------------
+dnl Since: 0.16
+dnl
+dnl Search for the pkg-config tool and set the PKG_CONFIG variable to
+dnl first found in the path. Checks that the version of pkg-config found
+dnl is at least MIN-VERSION. If MIN-VERSION is not specified, 0.9.0 is
+dnl used since that's the first version where most current features of
+dnl pkg-config existed.
+AC_DEFUN([PKG_PROG_PKG_CONFIG],
+[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
+m4_pattern_allow([^PKG_CONFIG(_(PATH|LIBDIR|SYSROOT_DIR|ALLOW_SYSTEM_(CFLAGS|LIBS)))?$])
+m4_pattern_allow([^PKG_CONFIG_(DISABLE_UNINSTALLED|TOP_BUILD_DIR|DEBUG_SPEW)$])
+AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])
+AC_ARG_VAR([PKG_CONFIG_PATH], [directories to add to pkg-config's search path])
+AC_ARG_VAR([PKG_CONFIG_LIBDIR], [path overriding pkg-config's built-in search path])
+
+if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
+	AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
+fi
+if test -n "$PKG_CONFIG"; then
+	_pkg_min_version=m4_default([$1], [0.9.0])
+	AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
+	if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
+		AC_MSG_RESULT([yes])
+	else
+		AC_MSG_RESULT([no])
+		PKG_CONFIG=""
+	fi
+fi[]dnl
+])dnl PKG_PROG_PKG_CONFIG
+
+dnl PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+dnl -------------------------------------------------------------------
+dnl Since: 0.18
+dnl
+dnl Check to see whether a particular set of modules exists. Similar to
+dnl PKG_CHECK_MODULES(), but does not set variables or print errors.
+dnl
+dnl Please remember that m4 expands AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+dnl only at the first occurence in configure.ac, so if the first place
+dnl it's called might be skipped (such as if it is within an "if", you
+dnl have to call PKG_CHECK_EXISTS manually
+AC_DEFUN([PKG_CHECK_EXISTS],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+if test -n "$PKG_CONFIG" && \
+    AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
+  m4_default([$2], [:])
+m4_ifvaln([$3], [else
+  $3])dnl
+fi])
+
+dnl _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
+dnl ---------------------------------------------
+dnl Internal wrapper calling pkg-config via PKG_CONFIG and setting
+dnl pkg_failed based on the result.
+m4_define([_PKG_CONFIG],
+[if test -n "$$1"; then
+    pkg_cv_[]$1="$$1"
+ elif test -n "$PKG_CONFIG"; then
+    PKG_CHECK_EXISTS([$3],
+                     [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`
+		      test "x$?" != "x0" && pkg_failed=yes ],
+		     [pkg_failed=yes])
+ else
+    pkg_failed=untried
+fi[]dnl
+])dnl _PKG_CONFIG
+
+dnl _PKG_SHORT_ERRORS_SUPPORTED
+dnl ---------------------------
+dnl Internal check to see if pkg-config supports short errors.
+AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
+        _pkg_short_errors_supported=yes
+else
+        _pkg_short_errors_supported=no
+fi[]dnl
+])dnl _PKG_SHORT_ERRORS_SUPPORTED
+
+
+dnl PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
+dnl   [ACTION-IF-NOT-FOUND])
+dnl --------------------------------------------------------------
+dnl Since: 0.4.0
+dnl
+dnl Note that if there is a possibility the first call to
+dnl PKG_CHECK_MODULES might not happen, you should be sure to include an
+dnl explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
+AC_DEFUN([PKG_CHECK_MODULES],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
+AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
+
+pkg_failed=no
+AC_MSG_CHECKING([for $1])
+
+_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
+_PKG_CONFIG([$1][_LIBS], [libs], [$2])
+
+m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
+and $1[]_LIBS to avoid the need to call pkg-config.
+See the pkg-config man page for more details.])
+
+if test $pkg_failed = yes; then
+	AC_MSG_RESULT([no])
+        _PKG_SHORT_ERRORS_SUPPORTED
+        if test $_pkg_short_errors_supported = yes; then
+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors --cflags --libs "$2" 2>&1`
+        else
+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors --cflags --libs "$2" 2>&1`
+        fi
+	# Put the nasty error message in config.log where it belongs
+	echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
+
+	m4_default([$4], [AC_MSG_ERROR(
+[Package requirements ($2) were not met:
+
+$$1_PKG_ERRORS
+
+Consider adjusting the PKG_CONFIG_PATH environment variable if you
+installed software in a non-standard prefix.
+
+_PKG_TEXT])[]dnl
+        ])
+elif test $pkg_failed = untried; then
+	AC_MSG_RESULT([no])
+	m4_default([$4], [AC_MSG_FAILURE(
+[The pkg-config script could not be found or is too old.  Make sure it
+is in your PATH or set the PKG_CONFIG environment variable to the full
+path to pkg-config.
+
+_PKG_TEXT
+
+To get pkg-config, see <http://pkg-config.freedesktop.org/>.])[]dnl
+        ])
+else
+	$1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
+	$1[]_LIBS=$pkg_cv_[]$1[]_LIBS
+        AC_MSG_RESULT([yes])
+	$3
+fi[]dnl
+])dnl PKG_CHECK_MODULES
+
+
+dnl PKG_CHECK_MODULES_STATIC(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
+dnl   [ACTION-IF-NOT-FOUND])
+dnl ---------------------------------------------------------------------
+dnl Since: 0.29
+dnl
+dnl Checks for existence of MODULES and gathers its build flags with
+dnl static libraries enabled. Sets VARIABLE-PREFIX_CFLAGS from --cflags
+dnl and VARIABLE-PREFIX_LIBS from --libs.
+dnl
+dnl Note that if there is a possibility the first call to
+dnl PKG_CHECK_MODULES_STATIC might not happen, you should be sure to
+dnl include an explicit call to PKG_PROG_PKG_CONFIG in your
+dnl configure.ac.
+AC_DEFUN([PKG_CHECK_MODULES_STATIC],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+_save_PKG_CONFIG=$PKG_CONFIG
+PKG_CONFIG="$PKG_CONFIG --static"
+PKG_CHECK_MODULES($@)
+PKG_CONFIG=$_save_PKG_CONFIG[]dnl
+])dnl PKG_CHECK_MODULES_STATIC
+
+
+dnl PKG_INSTALLDIR([DIRECTORY])
+dnl -------------------------
+dnl Since: 0.27
+dnl
+dnl Substitutes the variable pkgconfigdir as the location where a module
+dnl should install pkg-config .pc files. By default the directory is
+dnl $libdir/pkgconfig, but the default can be changed by passing
+dnl DIRECTORY. The user can override through the --with-pkgconfigdir
+dnl parameter.
+AC_DEFUN([PKG_INSTALLDIR],
+[m4_pushdef([pkg_default], [m4_default([$1], ['${libdir}/pkgconfig'])])
+m4_pushdef([pkg_description],
+    [pkg-config installation directory @<:@]pkg_default[@:>@])
+AC_ARG_WITH([pkgconfigdir],
+    [AS_HELP_STRING([--with-pkgconfigdir], pkg_description)],,
+    [with_pkgconfigdir=]pkg_default)
+AC_SUBST([pkgconfigdir], [$with_pkgconfigdir])
+m4_popdef([pkg_default])
+m4_popdef([pkg_description])
+])dnl PKG_INSTALLDIR
+
+
+dnl PKG_NOARCH_INSTALLDIR([DIRECTORY])
+dnl --------------------------------
+dnl Since: 0.27
+dnl
+dnl Substitutes the variable noarch_pkgconfigdir as the location where a
+dnl module should install arch-independent pkg-config .pc files. By
+dnl default the directory is $datadir/pkgconfig, but the default can be
+dnl changed by passing DIRECTORY. The user can override through the
+dnl --with-noarch-pkgconfigdir parameter.
+AC_DEFUN([PKG_NOARCH_INSTALLDIR],
+[m4_pushdef([pkg_default], [m4_default([$1], ['${datadir}/pkgconfig'])])
+m4_pushdef([pkg_description],
+    [pkg-config arch-independent installation directory @<:@]pkg_default[@:>@])
+AC_ARG_WITH([noarch-pkgconfigdir],
+    [AS_HELP_STRING([--with-noarch-pkgconfigdir], pkg_description)],,
+    [with_noarch_pkgconfigdir=]pkg_default)
+AC_SUBST([noarch_pkgconfigdir], [$with_noarch_pkgconfigdir])
+m4_popdef([pkg_default])
+m4_popdef([pkg_description])
+])dnl PKG_NOARCH_INSTALLDIR
+
+
+dnl PKG_CHECK_VAR(VARIABLE, MODULE, CONFIG-VARIABLE,
+dnl [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+dnl -------------------------------------------
+dnl Since: 0.28
+dnl
+dnl Retrieves the value of the pkg-config variable for the given module.
+AC_DEFUN([PKG_CHECK_VAR],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
+
+_PKG_CONFIG([$1], [variable="][$3]["], [$2])
+AS_VAR_COPY([$1], [pkg_cv_][$1])
+
+AS_VAR_IF([$1], [""], [$5], [$4])dnl
+])dnl PKG_CHECK_VAR
diff --git a/aclocal-flags b/aclocal-flags
deleted file mode 100755
index 49af718c8c..0000000000
--- a/aclocal-flags
+++ /dev/null
@@ -1,159 +0,0 @@
-#!/bin/sh
-#
-# This script returns the flags to be fed to "aclocal" to ensure that
-# it finds GLib's aclocal macros (we assume GTK+ is installed in the
-# same place as GLib) and pkg-config's aclocal macros.
-#
-# aclocal will search, by default, only in a directory in the same
-# tree where it was installed - e.g., if installed in "/usr/bin", it'll
-# search only in "/usr/share/aclocal", and if installed in "/usr/local/bin",
-# it'll search only in "/usr/local/share/aclocal".
-#
-# However, there is no guarantee that GLib, or pkg-config has been installed
-# there; if either of them hasn't been installed there, aclocal won't find
-# the autoconf macros for whichever of them wan't, and will complain
-# bitterly.
-#
-# So:
-#
-#	if pkg-config is found with a path that ends with "bin/pkg-config",
-#	and the "share/local" directory under the directory at the path
-#	that's the part of the pkg-config path preceding "bin/pkg-config"
-#	isn't the same directory as the directory reported by "aclocal
-#	--print-ac-dir", we include in our output a "-I" flag with that
-#	directory as its argument;
-#
-#	if the "share/local" directory under the directory reported by
-#	"pkg-config --variable=prefix glib-2.0" isn't the same directory
-#	as the directory reported by "aclocal --print-ac-dir", we include
-#	in our output a "-I" flag with the first of those directories as
-#	the argument.
-#
-# If either of them *is* the same directory as the directory reported by
-# "aclocal --print-ac-dir", and we supply that "-I" flag, "aclocal" will
-# look in that directory twice, and get well and truly confused, reporting
-# a ton of duplicate macro definitions.  This also means that if pkg-config
-# and Glib are installed with the same prefix, we should only supply one
-# "-I" flag for both of them.
-#
-
-#
-# OK, where will aclocal look by default?
-#
-aclocal_dir=`aclocal --print-ac-dir`
-
-#
-# And where do we want to make sure it looks?
-# Look for pkg-config first.
-#
-pkg_config_path=`command -v pkg-config 2>/dev/null`
-if [ -z "$pkg_config_path" ]
-then
-	#
-	# Either we don't have "command" (which is required by recent
-	# POSIX) or it didn't find pkg-config.
-	#
-	pkg_config_aclocal_dir=""
-else
-	#
-	# OK, we found pkg-config; attempt to find the prefix for it, by
-	# stripping off "bin/pkg-config".
-	#
-	pkg_config_prefix=`expr "$pkg_config_path" : '\(.*\)/bin/pkg-config'`
-	if [ -z "$pkg_config_prefix" ]
-	then
-		#
-		# Well, we couldn't strip it off, for whatever reason.
-		#
-		pkg_config_aclocal_dir=""
-	else
-		#
-		# Solaris 11's default pkg-config installation puts
-		# it in /usr/ccs/bin, but there's no /usr/ccs/share.
-		# Map /usr/ccs to /usr.
-		#
-		# Ubuntu 7.10 has /usr/X11R6/bin as a symbolic link
-		# to /usr/bin, but there's no /usr/X11R6/share.  If
-		# /usr/X11R6/bin is a symlink to /usr/bin, map
-		# /usr/X11R6 to /usr.
-		#
-		if [ "$pkg_config_prefix" = /usr/ccs ]
-		then
-			pkg_config_prefix=/usr
-		elif [ "$pkg_config_prefix" = /usr/X11R6 ]
-		then
-			if expr "`ls -ld /usr/X11R6/bin`" : '.*/usr/X11R6/bin -> .*/bin$' >/dev/null
-			then
-				pkg_config_prefix=/usr
-			fi
-		fi
-
-		#
-		# Now get the path of its aclocal directory.
-		#
-		pkg_config_aclocal_dir=$pkg_config_prefix/share/aclocal
-	fi
-fi
-
-#
-# Now see where glib is installed.
-#
-glib_prefix=`pkg-config --variable=prefix glib-2.0 2>/dev/null`
-
-#
-# Now get the path of its aclocal directory.
-#
-if [ -z "$glib_prefix" ]
-then
-	glib_aclocal_dir=""
-else
-	glib_aclocal_dir=$glib_prefix/share/aclocal
-fi
-
-#
-# Add our aclocal-fallback to the path.
-# We write out the -I flag for it, and strip off CR and LF, as we may
-# be writing more -I options, and we want all the options to be on
-# one line.
-#
-ac_missing_dir=`dirname $0`
-echo "-I $ac_missing_dir/aclocal-fallback" | tr -d '\012' | tr -d '\015'
-
-#
-# If there's no aclocal, aclocal_dir, which is the path where aclocal
-# searches, will be empty; if we didn't find pkg-config,
-# pkg_config_aclocal_dir, which is the path where it should search
-# for pkg-config's macros, will be empty.  Add pkg_config_aclocal_dir only
-# if both it and aclocal_dir are non-empty and different from each other.
-#
-if [ ! -z "$aclocal_dir" -a ! -z "$pkg_config_aclocal_dir" \
-    -a "$aclocal_dir" != "$pkg_config_aclocal_dir" ]
-then
-	echo " -I $pkg_config_aclocal_dir" | tr -d '\012' | tr -d '\015'
-fi
-
-#
-# If pkg-config doesn't know about glib-2.0, glib_aclocal_dir will be
-# empty.  (Should we just fail in that case?  Does that mean we don't
-# have GLib installed?)
-#
-# Add glib_aclocal_dir only if both it and aclocal_dir are non-empty and
-# different from each other *and* pkg_config_aclocal_dir is different from
-# glib_aclocal_dir.  (We don't need to check whether pkg_config_aclocal_dir
-# is empty; if it is, then either glib_aclocal_dir is also empty, in which
-# case we'll bail out before even looking at pkg_config_aclocal_dir, or
-# it's non-empty, in which case it obviously won't be equal to
-# pkg_config_aclocal_dir.)
-#
-if [ ! -z "$aclocal_dir" -a ! -z "$glib_aclocal_dir" \
-    -a "$aclocal_dir" != "$glib_aclocal_dir" \
-    -a "$pkg_config_aclocal_dir" != "$glib_aclocal_dir" ]
-then
-	echo " -I $glib_aclocal_dir" | tr -d '\012' | tr -d '\015'
-fi
-
-#
-# Put out the final line ending.
-#
-echo
-exit 0
diff --git a/autogen.sh b/autogen.sh
index e3219d737a..c1b0a549cc 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -135,7 +135,7 @@ fi
 
 $DIE
 
-aclocal_flags=`./aclocal-flags`
+aclocal_flags="-I ./aclocal-fallback"
 aclocalinclude="$ACLOCAL_FLAGS $aclocal_flags";
 echo $ACLOCAL $aclocalinclude
 $ACLOCAL $aclocalinclude || exit 1
diff --git a/echld/Makefile.am b/echld/Makefile.am
index ce54a69b09..b0a21dcb0f 100644
--- a/echld/Makefile.am
+++ b/echld/Makefile.am
@@ -21,8 +21,6 @@
 include Makefile.common
 include $(top_srcdir)/Makefile.am.inc
 
-ACLOCAL_AMFLAGS = `../aclocal-flags`
-
 AM_CPPFLAGS = -DWS_BUILD_DLL $(INCLUDEDIRS) $(WS_CPPFLAGS) \
 	$(GLIB_CFLAGS)
 
diff --git a/epan/Makefile.am b/epan/Makefile.am
index 1585861e7b..dca5fa619e 100644
--- a/epan/Makefile.am
+++ b/epan/Makefile.am
@@ -38,8 +38,6 @@ SUBDIRS = compress crypt ftypes dfilter dissectors nghttp2 wmem $(wslua_dir)
 
 DIST_SUBDIRS = $(SUBDIRS) $(wslua_dist_dir)
 
-ACLOCAL_AMFLAGS = `../aclocal-flags`
-
 AM_CPPFLAGS = $(INCLUDEDIRS) -I$(builddir)/wslua $(WS_CPPFLAGS) \
 	$(GLIB_CFLAGS) $(LUA_CFLAGS) $(LIBGNUTLS_CFLAGS) \
 	$(LIBGCRYPT_CFLAGS) $(LIBSMI_CFLAGS) $(LIBGEOIP_CFLAGS) \
diff --git a/extcap/Makefile.am b/extcap/Makefile.am
index 99395bacb4..4566c9d782 100644
--- a/extcap/Makefile.am
+++ b/extcap/Makefile.am
@@ -22,8 +22,6 @@
 include Makefile.common
 include ../Makefile.am.inc
 
-ACLOCAL_AMFLAGS = `../aclocal-flags`
-
 AM_CPPFLAGS = $(INCLUDEDIRS) $(WS_CPPFLAGS) $(GLIB_CFLAGS)
 
 MAINTAINERCLEANFILES = \
diff --git a/wiretap/Makefile.am b/wiretap/Makefile.am
index 76cb1a45f4..3e420aa377 100644
--- a/wiretap/Makefile.am
+++ b/wiretap/Makefile.am
@@ -22,8 +22,6 @@
 include Makefile.common
 include $(top_srcdir)/Makefile.am.inc
 
-ACLOCAL_AMFLAGS = `../aclocal-flags`
-
 AM_CPPFLAGS = $(INCLUDEDIRS) $(WS_CPPFLAGS) -DWS_BUILD_DLL $(GLIB_CFLAGS)
 
 noinst_LTLIBRARIES = libwiretap_generated.la
diff --git a/wsutil/Makefile.am b/wsutil/Makefile.am
index 3e12fa43fb..c69b9bc3c6 100644
--- a/wsutil/Makefile.am
+++ b/wsutil/Makefile.am
@@ -21,8 +21,6 @@
 include Makefile.common
 include $(top_srcdir)/Makefile.am.inc
 
-ACLOCAL_AMFLAGS = `../aclocal-flags`
-
 AM_CPPFLAGS = $(INCLUDEDIRS) $(WS_CPPFLAGS) -DWS_BUILD_DLL \
 	-DTOP_SRCDIR=\"$(abs_top_srcdir)\" 	\
 	-DDATAFILE_DIR=\"$(pkgdatadir)\" 	\