1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# $Id: configure.in,v 1.17 1998/11/18 04:02:17 gerald Exp $
dnl Process this file with autoconf to produce a configure script.
AC_INIT(etypes.h)
AM_INIT_AUTOMAKE(ethereal, 0.5.0)
dnl Check for CPU / vendor / OS
AC_CANONICAL_HOST
dnl Checks for programs.
AC_PROG_CC
AC_PROG_RANLIB
# If we're running gcc, add '-Wall' to CFLAGS.
AC_MSG_CHECKING(to see if we can add '-Wall' to CFLAGS)
if test x$GCC != x ; then
CFLAGS="-Wall $CFLAGS"
AC_MSG_RESULT(yes)
else
AC_MSG_RESULT(no)
fi
# Create DATAFILE_DIR #define for config.h
DATAFILE_DIR=$sysconfdir
DATAFILE_DIR=`(
test "x$prefix" = xNONE && prefix=$ac_default_prefix
test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
eval echo "$DATAFILE_DIR"
)`
AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
AC_SUBST(DATAFILE_DIR)
# If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
# link directory.
case "$host_os" in
solaris*)
AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
if test x$LD_LIBRARY_PATH != x ; then
LIBS="$LIBS -R$LD_LIBRARY_PATH"
AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
else
AC_MSG_RESULT(no -- this may be a problem in a few seconds)
fi
;;
esac
# GTK checks
AM_PATH_GTK(1.0.0, CFLAGS="$CFLAGS $GTK_CFLAGS" LIBS="$LIBS $GTK_LIBS",
AC_MSG_ERROR(GTK+ distribution not found.))
# Pcap checks
AC_CHECK_HEADER(net/bpf.h,, AC_MSG_ERROR(Header file net/bpf.h not found.))
AC_CHECK_HEADER(pcap.h,, AC_MSG_ERROR(Header file pcap.h not found.))
AC_CHECK_LIB(pcap, pcap_open_offline,, AC_MSG_ERROR(Library libpcap not found.))
# Evidently, some systems have pcap.h, etc. in */include/pcap
AC_MSG_CHECKING(for extraneous pcap header directories)
found_pcap_dir=""
for pcap_dir in /usr/include/pcap /usr/local/include/pcap
do
if test -d $pcap_dir ; then
LIBS="$LIBS -L$pcap_dir"
found_pcap_dir=" $found_pcap_dir -L$pcap_dir"
fi
done
if test "$found_pcap_dir" != "" ; then
AC_MSG_RESULT(found --$found_pcap_dir added to LIBS)
else
AC_MSG_RESULT(not found)
fi
# Wiretap check
AC_MSG_CHECKING(whether to include wiretap library)
AC_ARG_WITH(wiretap,
[ --with-wiretap Include wiretap library.
--without-wiretap Don't include wiretap library (default)],
[ case "$withval" in
yes)
AC_MSG_RESULT(yes)
AC_DEFINE(WITH_WIRETAP)
CFLAGS="$CFLAGS -Iwiretap"
LIBWIRETAP_A="wiretap/libwiretap.a"
WIRETAP_DIR="wiretap"
;;
*)
AC_MSG_RESULT(no)
LIBWIRETAP_A=""
WIRETAP_DIR=""
;;
esac ],
AC_MSG_RESULT(no)
)
AC_SUBST(LIBWIRETAP_A)
AC_SUBST(WIRETAP_DIR)
dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h strings.h sys/ioctl.h sys/time.h unistd.h stdarg.h)
AC_CHECK_HEADERS(sys/sockio.h sys/types.h netinet/in.h)
dnl Checks for typedefs, structures, and compiler characteristics.
# AC_C_CONST
# We need to know whether "struct sockaddr" has an "sa_len" member
# for get_interface_list().
AC_ETHEREAL_STRUCT_SA_LEN
# We must know our byte order
AC_C_BIGENDIAN
dnl Checks for library functions.
AC_PROG_GCC_TRADITIONAL
AC_CHECK_FUNC(socket,, AC_MSG_ERROR(Function 'socket' not found.))
# If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
# then this won't work.
SNPRINTF_C=""
SNPRINTF_O=""
AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
if test "$ac_cv_func_snprintf" = no ; then
SNPRINTF_C="snprintf.c"
SNPRINTF_O="snprintf.o"
fi
AC_SUBST(SNPRINTF_C)
AC_SUBST(SNPRINTF_O)
AM_CONFIG_HEADER(config.h)
if test x$WIRETAP_DIR != x ; then
AC_CONFIG_SUBDIRS(wiretap)
fi
AC_OUTPUT(Makefile)
|
